HexaCone/orbite.pov

/*
 *	H E X A C O N E   -   O R B I T E
 */

#version 3.7;

#include  "globals.inc"

#include  "contexte.inc"
#include  "elements.inc"
#include  "hexabenz.inc"

// =======================================================
#declare R_planete = 1.42;

#declare Croute = object
{
#local R1 = R_planete * 1.05;
#local R2 = R_planete * 1.03;
#local HC = R_planete * 0.11;
#local BN = R_planete * 3;

difference {
	sphere { 0, R1 }
	sphere { 0, R2 }
	box { <-HC, -BN, -BN>, <HC, BN, BN> }
	box { <-BN, -HC, -BN>, <BN, HC, BN> }
	box { <-BN, -BN, -HC>, <BN, BN, HC> }
	}
texture {
	pigment { color rgb <0.20, 0.40, 0.10>  }
	finish { reflection 0.25 }
	}
}

#declare Boule = object
{
sphere { 0, R_planete }
texture {
	pigment { rgb <0.70, 0.50, 0.70> }
	finish { reflection 0.25 }
	}
}

#declare Planete = object
{
union	{
	object { Croute }
	object { Boule }
	}
}
// =======================================================

#local RO = 4.15;
#local CK = NormClock * 7.87;

#declare PosX = RO * sin(CK);
#declare PosY = 0;
#declare PosZ = RO * cos(CK);
object { HexaBenz ()
	rotate -y*CK*2.333 translate <PosX, PosY, PosZ>
	}
#declare PosX = RO * sin(CK+2.12);
#declare PosY = 0;
#declare PosZ = RO * cos(CK+2.23);
object { HexaCone ()
	rotate  y*CK*3.222 translate <PosX, PosY, PosZ>
	}

object { Planete rotate (-clock*0.21)*y }
light_source { <19, 6,  15>, rgb <0.77, 0.79, 0.80> }

camera	{
	location	<3, 1.50, 7.59>
	look_at		<0.0, 0.0, 0>
	focal_point	<0.07, 0.0, 0>
	aperture	0.046
	blur_samples	30
	angle		62
	}