HexaCone/contexte.inc

/*
 *   nouveau projet Thu Dec  5 11:37:05 AM UTC 2024
 */

/*   voir aussi le fichier 'globals.inc'   */

/* ------------------------------------------------------------ */

#declare Rhxba = 0.30;
#declare R2hxba = Rhxba * 0.48;

#declare HexaBalls = object
{
merge	{
	sphere { 0, Rhxba }
	#local E = Rhxba * 1.260;
	sphere { 0, R2hxba	translate <-E,  0,  0>	}
	sphere { 0, R2hxba	translate < E,  0,  0>	}
	sphere { 0, R2hxba	translate < 0, -E,  0>	}
	sphere { 0, R2hxba	translate < 0,  E,  0>	}
	sphere { 0, R2hxba	translate < 0,  0, -E>	}
	sphere { 0, R2hxba	translate < 0,  0,  E>	}
	}
}

#declare Les_Bibelots = object
{
union	{
	object	{ HexaBalls
		texture { Lightning1 scale 0.33 }
		rotate <clock/3, clock/6, clock/9>
		translate <3, -1.6+1.01*Cos_010(NormClock), 5>
		}

	object	{ HexaBalls
		texture { Lightning2 scale 0.56 }
		// rotate <-clock, clock*0.33333, clock>
		translate <5, -1+0.42*Cos_010(NormClock), -4>
		}
	}
}
/* ------------------------------------------------------------ */
#declare RHBlo  = 0.24;
#declare RHBlo2 = RHBlo * 0.666;

#declare HexaBlob = object
{
blob			{
	// threshold 0.01 + NormClock
	threshold 0.01
	sphere { <0, 0, 0>, RHBlo, 1 }
	#local E = RHBlo * 1.210;
	#local W = 0.1;
	sphere { <-E,  0,  0>, RHBlo2, W }
	sphere { < E,  0,  0>, RHBlo2, W }
	sphere { < 0, -E,  0>, RHBlo2, W }
	sphere { < 0,  E,  0>, RHBlo2, W }
	sphere { < 0,  0, -E>, RHBlo2, W }
	sphere { < 0,  0,  E>, RHBlo2, W }
	}
}

// =======================================================

#declare Le_Sol = object
{
height_field {
	png "datas/hf.png"
	smooth
	translate <-.5, 0, -.5>
	scale <21, 0.88, 21>
	texture {
		pigment { color DarkGreen  }
		normal { bumps 0.035 scale 0.186 }
		finish  { phong 0.125 }
		}
	}
}

#declare Repere = object
{
union	{
	cylinder { 0, <1, 0, 0>, 0.007 pigment { color Red } }
	cylinder { 0, <0, 0, 1>, 0.007 pigment { color Blue } }
	}
}

#declare Les_Lumieres = object
{
union {
	#if (1)
	light_source {
		<0.3, 2.50,  2.8>	color Gray90
		spotlight
		radius 14 falloff 10 tightness 10
		point_at <0, 0.95, 0.22222222>
		}
	#end

	#if ( (clock>166) & (clock<213) )
	light_source {
		<2, 0.30, -2>	color Yellow
		spotlight
		radius 12 falloff 20 tightness 10
		point_at <-0.08, 0.80, 0.17>
		}
	#end

	#if (1)
	light_source {
		<-5, 5.60, 8>
		#if ( (clock > 290) & (clock<344) )
		 #local Couleur = rgb <0.20, 0.20, 0.90>;
		#else
		 #local Couleur = rgb <0.80, 0.80, 0.70>;
		#end
		color Couleur
		spotlight
	radius 9 falloff 10 tightness 5
	point_at <0, 0.95, -0.22>
		}
	#end
	}
}

// #declare Le_Ciel = object
// {
sky_sphere {
	pigment {
		gradient y
		color_map {
			[ 0.2  color Gray10	]
			[ 0.4  color Gray60	]
			[ 0.7  color Black	]
			[ 0.8  color White	]
			[ 1.0  color Gray10	]
			}
		turbulence 3.14159 + 0.91 * Cos_010(NormClock)
		scale 1.804
		// translate -1
		}
	#local Kem = 0.15;
	emission rgb <Kem, Kem, Kem>
	}
// }

/* ------------------------------------------------------------ */
/*
 *	Et on rassemble tous les éléments...
 */
#declare Le_Decor = object
{
union	{
	object { Le_Sol }
	object { Les_Bibelots }
	object { Les_Lumieres }
	}
}
/* ------------------------------------------------------------ */