HexaCone/contexte.inc

/*
 *   nouveau projet Thu Dec  5 11:37:05 AM UTC 2024
 */


#declare Rng2 = seed(now*24*60*60);
#declare foo = rand(Rng2);

#declare  NormClock = clock / 360.0;

/* ------------------------------------------------------------ */

#macro Cos_01( X )
  (0.5-0.5*cos( 3.141592654 * X))
#end
#macro Cos_010( X )
  (0.5-0.5*cos( 2 * 3.141592654 * X))
#end

/* ------------------------------------------------------------ */

#declare Rhxba = 0.30;
#declare R2hxba = Rhxba * 0.48;

#declare HexaBalls = object
{
merge	{
	sphere { 0, Rhxba }
	#local E = Rhxba * 1.260;
	sphere { 0, R2hxba	translate <-E,  0,  0>	}
	sphere { 0, R2hxba	translate < E,  0,  0>	}
	sphere { 0, R2hxba	translate < 0, -E,  0>	}
	sphere { 0, R2hxba	translate < 0,  E,  0>	}
	sphere { 0, R2hxba	translate < 0,  0, -E>	}
	sphere { 0, R2hxba	translate < 0,  0,  E>	}
	}
}

object	{ HexaBalls
	texture { Lightning1 scale 0.33 }
	rotate <clock/3, clock/6, clock/9>
	translate <3, 0.72, 5>
	}

object	{ HexaBalls
	texture { Lightning2 scale 0.33 }
	rotate <-clock, clock*0.62, clock>
	translate <5, 0.92, -4>
	}

/* ------------------------------------------------------------ */

height_field {
	png "datas/hf.png"
	smooth
	translate <-.5, 0, -.5>
	scale <21, 0.88, 21>
	texture {
		pigment { color DarkGreen  }
		normal { bumps 0.035 scale 0.186 }
		finish  { phong 0.125 }
		}
	}


#declare Repere = object
{
union	{
	cylinder { 0, <1, 0, 0>, 0.007 pigment { color Red } }
	cylinder { 0, <0, 0, 1>, 0.007 pigment { color Blue } }
	}
}

#if (1)
light_source {
	<0.3, 2.50,  2.8>	color Gray90
	spotlight
	radius 14
	falloff 10
	tightness 10
	point_at <0, 0.95, 0.22222222>
	}
#end

#if ( (clock>166) & (clock<213) )
light_source {
	<2, 0.30, -2>	color Yellow
	spotlight
	radius 12
	falloff 20
	tightness 10
	point_at <-0.08, 0.80, 0.17>
	}
#end

#if (1)
light_source {
	<-5, 5.60, 8>
	#if ( (clock > 290) & (clock<344) )
	  #local Couleur = rgb <0.20, 0.20, 0.90>;
	#else
	  #local Couleur = rgb <0.80, 0.80, 0.70>;
	#end
	color Couleur
	spotlight
	radius 9
	falloff 10
	tightness 5
	point_at <0, 0.95, -0.22>
	}
#end