HexaCone/orbite.pov

/*
 *	H E X A C O N E   -   O R B I T E
 */

#version 3.7;

#include  "globals.inc"

#include  "colors.inc"
#include  "metals.inc"
#include  "textures.inc"
#include  "stones.inc"

#include  "contexte.inc"
#include  "elements.inc"

// =======================================================
#declare R_planete = 2.1;

#declare Croute = object
{
#local R1 = R_planete * 1.05;
#local R2 = R_planete * 1.03;
#local HC = R_planete * 0.11;
#local BN = R_planete * 3;

difference {
	sphere { 0, R1 }
	sphere { 0, R2 }
	box { <-HC, -BN, -BN>, <HC, BN, BN> }
	box { <-BN, -HC, -BN>, <BN, HC, BN> }
	box { <-BN, -BN, -HC>, <BN, BN, HC> }
	}
texture {
	pigment { color Gray10 }
	}
}

#declare Boule = object
{
sphere { 0, R_planete }
texture {
	pigment { color Gray80 }
	finish { reflection 0.500 }
	}
}

#declare Planete = object
{
union	{
	object { Croute }
	object { Boule }
	}
}
// =======================================================

#local RO = 4.10;
#local CK = NormClock * 7.87;

#declare PosX = RO * sin(CK);
#declare PosY = 0;
#declare PosZ = RO * cos(CK);

object { HexaCone
	rotate -y*CK translate <PosX, PosY, PosZ>
	}

object { Planete rotate (-clock*0.21)*y }
light_source { <19, 7,  14>, rgb <0.77, 0.79, 0.80> }

camera	{
	location	<3, 2.01, 7.59>
	look_at		<0.0, 0.0, 0>
	angle		58
	}