Fortraneries/GravityField/vision.pov

/*
 *	Visualisation en 3d d'une tentative de champ gravitationnel
 *
 *	tTh novembre 2022
 */

#version 3.7;
global_settings {
		ambient_light rgb <0.07, 0.05, 0.05>
		assumed_gamma 1.0
		max_trace_level 6
		}

#include  "colors.inc"

#declare NormClock = clock / 2000.01;

// ----------------------------------------------------------------------

#declare HFDIR  = "WS/nanim/";
#declare HFCK   = mod(clock, 2000);
#declare HFNAME = concat(HFDIR, str(HFCK , -5, 0), ".pgm");
#debug concat("- - - - - - - ", HFNAME, "\n")

#declare GravityField = object
{
height_field {
        pgm	HFNAME
        smooth    // on
        translate <-0.5, 0, -0.5>
	}
texture {
	pigment { color Gray80 }
	finish { phong 0.50 }
	}
}

object { GravityField scale <4, 0.70, 4> }

// ----------------------------------------------------------------------

cylinder { <0, -0.5, 0>, <0, 1, 0>, 0.0175 pigment { color Red } }

light_source { < -2, 9.3, -7>	color Gray90			}
light_source { < -6, 9.3, -8>	color Orange*0.75		}
light_source { < -15, 2.3, 17>	color Green*0.25			}

// ----------------------------------------------------------------------

camera	{
	location	<-8, 4-NormClock, 1 + 3*NormClock>
	look_at		<0, 0, 0>
	right		x*image_width/image_height
	angle		34
	}

// ----------------------------------------------------------------------