/*

		La Gare !-)
		-----------

*/

#local H_quai = 110;

#local Decoupe_porte_gare = object
{
merge	{
	box { <-120, -1, -20>, <120, 240, 20> }
	cylinder { <0, 0, -20>, <0, 0, 20>, 51
		scale <1, 0.8, 1> translate y*230 }
	}
}

#declare Corps_Gare = object
{
difference
	{
	box { <-600, 0, -200>, <600, 400, 200> }
	box { <-590, 0, -190>, <590, 390, 190> }
	#for (foo, -1, 3)
		#declare px = foo * 165;
		box { <px-42, 110, -222>, <px+42, 255, 222> }
	#end
	object { Decoupe_porte_gare translate <-430, 0, -200> }
	}
texture {
	pigment { color White }
	finish { phong 0.5 }
	}
}

#declare Quai_Gare = object
{
box { <-700, 0, 220>, <700, H_quai, -420> }

pigment { color White }
finish { phong 0.4 }
}

#include "incs/enseigne.inc"

#declare Gare = object
{
union	
	{
	object { Corps_Gare translate y*H_quai }
	object { Quai_Gare }
	object { Enseigne_Hello scale 15 translate <0, 465, -210>  }
	}
}

/*-----------------------------------------------------
	je suis le raytraceur des lilas.
-----------------------------------------------------*/