/*
 *		H E X A C O N E
 *
 *   nouveau projet du Thu Dec  5 11:37:05 AM UTC 2024
 */

#version 3.7;

#include  "globals.inc"

#declare NO_DYNAMIC = 0;
#include  "all.inc"

// =======================================================

#local Y_mean   = 0;
#local Y_count  = 0;

#for (idX, -3, 3)
  #for (idZ, -3, 3)

    #local posX = (idX * 4.72)  + (rand(Rng1)-0.5);
    #local posY = 3.2 + (NormClock * 12 * (rand(Rng1)+0.75));
    #local posZ = (idZ * 4.39) ;
    #local Rx   = (rand(Rng1) - 0.5) * 12;
    #local Ry   = (rand(Rng1) - 0.5) * (24+NormClock);
    #local Rz   = (rand(Rng1) - 0.5) * 11;

// #debug concat("X  ", str(posX,7,3), "  Z  ", str(posZ,7,3), "\n")
// #debug concat("position Z  ", str(posZ,7,3),"\n")

    #declare Limit = 1.470;
    #if ( (abs(posX)>Limit) & (abs(posZ)>Limit) )  // position
      #local Y_mean  = Y_mean  + posY;
      #local Y_count = Y_count + 1;
      #local       R = rand(Rng1);
      #if (R < 0.30)
        object { HexaCone () rotate <Rx, Ry, Rz>
			translate <posX, posY, posZ> }
      #elseif (R < 0.60)
        object { HexaStar   rotate y*90 rotate <Rx, Ry, Rz>
			translate <posX, posY, posZ> }
      #else
        object { HexaBenz () rotate <Rx, Ry, Rz>
			translate <posX, posY, posZ> }
      #end
    #end	// if position...
  #end		// loop idX
#end		// loop idZ

// =======================================================

object { Le_Decor }

//  object { Repere scale 5 translate y }

#local CamX = -8.7    + ( 6.9   * Cos_01(NormClock));
#local CamY =  0.42   + (17.36  * Cos_01(NormClock));
#local CamZ =  122    - (21.9   * Cos_01(NormClock));

#local LatY = (Y_mean / Y_count) - (0.5*NormClock);
#debug concat("Lat Y  ", str(LatY, 7, 3),"\n")

camera	{
	location	<CamX, CamY, CamZ>
	look_at		<0.0, LatY, 0>
	right		<image_width/image_height, 0, 0>
	angle		56 - (21 * NormClock)
	}