/*
 *		BLOUBSWORLD
 *  new Sun 06 Feb 2022 01:33:39 PM CET, rue Ernest Renan
 */
#version 3.7;

global_settings {
                ambient_light rgb <0.12, 0.04, 0.04>
                assumed_gamma 1.0
                }

#include  "colors.inc"

#include  "nbimg.inc"

#declare NormClock = clock / NbImg;

//  ----------------------------------------------------------

#include  "bloubs.inc"

object	{
	Bloubs
	texture {
		pigment { color Gray60 } 
		finish { phong 0.58 specular 0.45 }
		}
	}

plane	{
	<0, 1, 0>, 0
	texture {
		pigment { color Gray05 } 
		finish { phong 0.18 metallic 0.45 }
		}
	}

//  ----------------------------------------------------------

#declare BH = 5;		// H = taille en horizontal
#declare BV = 5;		// V = taille en vertical
#declare BR = 0.028;

#declare Une_Borne = object
{
merge	{
	cylinder { <0, 0, 0>, <0, BV,   0>, BR     }
	cylinder { <0, 0, 0>, <0, 0.04, 0>, BR*6   }
	}
}

#declare Cadre_Haut = object
{
merge {
	cylinder { <-BH, 0, -BH>, <-BH, 0,  BH>, BR    }
	cylinder { < BH, 0, -BH>, < BH, 0,  BH>, BR    }
	cylinder { < BH, 0, -BH>, <-BH, 0, -BH>, BR    }
	cylinder { < BH, 0,  BH>, <-BH, 0,  BH>, BR    }
	}
pigment { color Gray50 }
}

#declare Les_Bornes = object
{
union	{
	object { Cadre_Haut translate y*(BV-0.05) }

	object { Une_Borne translate <-BH, 0, -BH> pigment { color Blue }  }
	object { Une_Borne translate < BH, 0, -BH> pigment { color Green } }
	object { Une_Borne translate <-BH, 0,  BH> pigment { color Green } }
	object { Une_Borne translate < BH, 0,  BH> pigment { color Red }   }
	}
}

object { Les_Bornes }

//  ----------------------------------------------------------

light_source { <9, 22, -17> color Gray80 }
light_source { <11, 19,   9> color Gray60 }

#declare HCAM = 5 + (11 * NormClock);

#fopen LC "log.camera" append
#write (LC, clock, "  ", NormClock, "  ", HCAM, "\n")
#fclose LC

camera  {
	location   <7, HCAM, -16>
	look_at    <0,    1,   0>
	right           x*image_width/image_height
	angle		50
	}