/*
 *		BLOUBSWORLD
 *  new Sun 06 Feb 2022 01:33:39 PM CET, rue Ernest Renan
 */
#version 3.7;

global_settings {
                ambient_light rgb <0.12, 0.04, 0.04>
                assumed_gamma 1.0
                }

#include  "colors.inc"

#include  "nbimg.inc"

#declare NormClock = clock / NbImg;

//  ----------------------------------------------------------

#include  "bloubs.inc"

object	{
	Bloubs
	finish { phong 0.33 specular 0.95 }
	}

plane	{
	<0, 1, 0>, 0
	texture {
		pigment { color Gray05 } 
		finish { phong 0.18 metallic 0.45 }
		}
	}

//  ----------------------------------------------------------

#declare BH = 5;		// H = taille en horizontal
#declare BV = 5;		// V = taille en vertical
#declare BR = 0.035;

#declare Une_Borne = object
{
merge	{
	cylinder { <0, 0, 0>, <0, BV,   0>, BR     }
	cylinder { <0, 0, 0>, <0, 0.04, 0>, BR*6   }
	}
}

#declare Un_Cadre = object
{
merge {
	#local Ruc = BR * 0.78;
	cylinder { <-BH, 0, -BH>, <-BH, 0,  BH>, Ruc    }
	cylinder { < BH, 0, -BH>, < BH, 0,  BH>, BR    }
	cylinder { < BH, 0, -BH>, <-BH, 0, -BH>, BR    }
	cylinder { < BH, 0,  BH>, <-BH, 0,  BH>, Ruc    }
	}
pigment { color Gray40 }
}

#declare Les_Bornes = object
{
union	{
	#local E = 0.12;
	object { Un_Cadre translate y*(BV-E)    }
	object { Un_Cadre translate y*E         }

	object { Une_Borne translate <-BH, 0, -BH> pigment { color Blue }  }
	object { Une_Borne translate < BH, 0, -BH> pigment { color Green } }
	object { Une_Borne translate <-BH, 0,  BH> pigment { color Green } }
	object { Une_Borne translate < BH, 0,  BH> pigment { color Red }   }
	}
}

object { Les_Bornes }

//  ----------------------------------------------------------
#local D = 0.016;

#declare Fleche = object
{
merge	{
	sphere   { <-0.05, 0, 0>, D }
	cylinder { <1, 0, 0>, <-0.05, 0, 0>, D }
	cone     { <1, 0, 0>, D*3.1, <1.10, 0, 0>, 0.0001 }
	}
}
#declare Repere = object
{
union {
	object   { Fleche		pigment { color Red }}
	object   { Fleche rotate z*90	pigment { color Green }}
	object   { Fleche rotate y*270	pigment { color Blue }}
	}
}
//  ----------------------------------------------------------

// object { Repere scale 2+(1.9*NormClock) translate y*2.5 }

light_source { <9, 22, -17> color Gray80 }
light_source { <11, 19,   9> color Gray60 }

#declare XCAM = 8 -( NormClock*3 );
#declare YCAM = 5 + (11 * NormClock);

#fopen LC "log.camera" append
#write (LC, clock, "  ", NormClock, "  ", YCAM, "\n")
#fclose LC

camera  {
	location   <XCAM, YCAM, -16>
	look_at    <0,    1,   0>
	right           x*image_width/image_height
	angle		48
	}