/*
 *		BLOUBSWORLD
 *  new Sun 06 Feb 2022 01:33:39 PM CET, rue Ernest Renan
 */
#version 3.7;

global_settings {
                ambient_light rgb <0.12, 0.01, 0.01>
                assumed_gamma 1.0
                }

#include  "colors.inc"

#include  "nbimg.inc"

#declare NormClock = clock / NbImg;

//  ----------------------------------------------------------

#include  "bloubs.inc"

object	{
	Bloubs
	texture {
		pigment { color Gray60 } 
		finish { phong 0.58 specular 0.45 }
		}
	}

plane	{
	<0, 1, 0>, 0
	texture {
		pigment { color Gray05 } 
		finish { phong 0.18 metallic 0.45 }
		}
	}

//  ----------------------------------------------------------

#declare BH = 5;
#declare BV = 5;
#declare BR = 0.025;

#declare Une_Borne = object
{
union	{
	cylinder { <0, 0, 0>, <0, BV,   0>, BR     }
	cylinder { <0, 0, 0>, <0, 0.02, 0>, BR*6   }
	}
}

#declare Les_Bornes = object
{
union	{
	object { Une_Borne translate <-BH, 0, -BH> pigment { color Blue }  }
	object { Une_Borne translate < BH, 0, -BH> pigment { color Green } }
	object { Une_Borne translate <-BH, 0,  BH> pigment { color Green } }
	object { Une_Borne translate < BH, 0,  BH> pigment { color Red }   }
	}
}

object { Les_Bornes }

//  ----------------------------------------------------------

light_source { <9, 22, -17> color Gray80 }
light_source { <11, 19,   9> color Gray60 }

#declare HCAM = 5 + (11 * NormClock);

#fopen LC "log.camera" append
#write (LC, clock, "  ", NormClock, "  ", HCAM, "\n")
#fclose LC

camera  {
	location   <7, HCAM, -16>
	look_at    <0,    1,   0>
	right           x*image_width/image_height
	angle		50
	}