/*
 *          Phytotron
 * lecture des capteurs de temperature LM35
 */
/* -------------------------------------------------- */

#define NBVAL   4
#define DELAI   1000

typedef struct {
  unsigned short    magic;
  char              tag[4];
  short             delai;
  } Global;

Global parametres;

/* -------------------------------------------------- */
void setup() {
  Serial.begin(9600);
  pinMode(LED_BUILTIN, OUTPUT);
  
  Serial.print("\n");

  phytocli();         /* XXX */
  
  /* XXX */
  /*  changing the voltage reference of the ADC
   *  greatly increase the prcision on the limited
   *  range of our temperatures.
   */
  analogReference(INTERNAL1V1); // Pour Arduino Mega2560
  Serial.print("\n\n");
  delay(1000);
  Serial.print("M running now\n");
  
}
/* ================================================== */
/*
 * the light captor is on A4 pin
 */
void readlight(void)
{
  short value;
  delay(100);
  value = analogRead(A4);
  Serial.print("L ");
  Serial.print(value);
  Serial.print('\n');
}
/* ================================================== */
short adc_pins[] = { A0, A1, A2, A3 };
#define NB_PASSE  4
/* -------------------------------------------------- */
void updatevalues(short *ptr)
{
  short foo, pass;

  for (foo=0; foo<NBVAL; foo++) { ptr[foo] = 0; }
  
  digitalWrite(LED_BUILTIN, HIGH);
  for (pass=0; pass<NB_PASSE; pass++) {
    for (foo=0; foo<NBVAL; foo++) {
      ptr[foo] += analogRead(adc_pins[foo]);
      delay(50);
      }
    }
    
  for (foo=0; foo<NBVAL; foo++) { ptr[foo] /= NB_PASSE; }
  
  digitalWrite(LED_BUILTIN, LOW);
}
/* -------------------------------------------------- */
void sendvalues(short *ptr)
{
  int foo;

  Serial.print("T");
  for (foo=0; foo<NBVAL; foo++) {
    Serial.print(" ");
    Serial.print(ptr[foo]);
    }
  Serial.print('\n');
}
/* -------------------------------------------------- */
void update_and_send(void)
{
  short values[NBVAL];
  
  updatevalues(values);
  sendvalues(values);
 
}
/* ================================================== */
void loop() {
  static int foo = 0;
  update_and_send();

  if (foo++ > 5) {
    readlight();    foo = 0;
    }

 /* check for CLI request */
 if (Serial.available() && 0x55==Serial.read())
    {
    Serial.println("M cli request");
    phytocli();
    }
 
  delay(DELAI);
}

/* -------------------------------------------------- */